{
  description = "hakyll-nix-template";

  nixConfig.bash-prompt = "[nix]λ ";

  inputs.nixpkgs.url = "nixpkgs/nixos-22.05";

  outputs = { nixpkgs, self }: let
    system = "x86_64-linux";
    overlays = [ (import ./nix/haskell-overlay.nix) ];
    pkgs = import nixpkgs { inherit overlays system; };
  in {
    overlays = {
      haskell-overlay = import ./nix/haskell-overlay.nix;
      default = self.overlays.haskell-overlay;
    };

    packages.${system} = with pkgs.myHaskellPackages; {
      inherit ssg website;
      default = website;
    };

    apps.${system} = {
      hakyll-site = let
        drv = self.packages.${system}.ssg;
        exePath = "/bin/hakyll-site";
      in {
        type = "app";
        program = "${drv}${exePath}";
      };
      default = self.apps.${system}.hakyll-site;
    };

    devShells.${system}.default = pkgs.myHaskellPackages.shellFor {
      packages = p: [ p.ssg ];

      buildInputs = with pkgs.myHaskellPackages; [
        # ssg

        # Helpful tools for `nix develop` shells
        ghcid                   # https://github.com/ndmitchell/ghcid
        haskell-language-server # https://github.com/haskell/haskell-language-server
        hlint                   # https://github.com/ndmitchell/hlint
        ormolu                  # https://github.com/tweag/ormolu
      ];

      withHoogle = true;
    };

    hydraJobs = {
      ssg.${system} = self.packages.${system}.ssg;
      website.${system} = self.packages.${system}.website;
    };
  };
}